add dbms_output enable/disable/get_lines and code coverage

PhilippSalvisberg · PhilippSalvisberg · commit 53b906eb999e · 2018-10-18T00:46:03.000+02:00
diff --git a/sqldev/src/main/java/org/utplsql/sqldev/dal/UtplsqlDao.xtend b/sqldev/src/main/java/org/utplsql/sqldev/dal/UtplsqlDao.xtend
@@ -15,15 +15,20 @@
  */
  package org.utplsql.sqldev.dal
 
+import java.sql.CallableStatement
 import java.sql.Connection
+import java.sql.SQLException
+import java.sql.Types
 import java.util.List
 import org.oddgen.sqldev.generators.model.Node
 import org.springframework.dao.DataAccessException
 import org.springframework.dao.EmptyResultDataAccessException
 import org.springframework.jdbc.core.BeanPropertyRowMapper
+import org.springframework.jdbc.core.CallableStatementCallback
 import org.springframework.jdbc.core.JdbcTemplate
 import org.springframework.jdbc.datasource.SingleConnectionDataSource
 import org.utplsql.sqldev.model.ut.Annotation
+import org.utplsql.sqldev.model.ut.OutputLines
 
 class UtplsqlDao {
 	public static val UTPLSQL_PACKAGE_NAME = "UT" 
@@ -472,6 +477,79 @@ class UtplsqlDao {
 		val jdbcTemplate = new JdbcTemplate(new SingleConnectionDataSource(conn, true))
 		val nodes = jdbcTemplate.query(sql, new BeanPropertyRowMapper<Node>(Node))
 		return nodes		
-	}	 
+	}
+	
+	def void enableDbmsOutput() {
+		// equivalent to "set serveroutput on size unlimited"
+		jdbcTemplate.update('''
+			BEGIN
+				sys.dbms_output.enable(NULL);
+			END;
+		''')
+	}
+	
+	def void disableDbmsOutput() {
+		jdbcTemplate.update('''
+			BEGIN
+				sys.dbms_output.disable;
+			END;
+		''')
+	}
+
+	def String getDbmsOutput() {
+		return getDbmsOutput(1000)
+	}
+	
+	def String getDbmsOutput(int bufferSize) {
+		val sb = new StringBuffer
+		val sql = '''
+			BEGIN
+				sys.dbms_output.get_lines(?, ?);
+			END;
+		'''
+		var OutputLines ret 
+		do {
+			ret = jdbcTemplate.execute(sql, new CallableStatementCallback<OutputLines>() {
+				override OutputLines doInCallableStatement(CallableStatement cs) throws SQLException, DataAccessException {
+					cs.registerOutParameter(1, Types.ARRAY, "DBMSOUTPUT_LINESARRAY");
+					cs.registerOutParameter(2, Types.INTEGER)
+					cs.setInt(2, bufferSize)
+					cs.execute
+					val out = new OutputLines
+					out.lines = cs.getArray(1).array as String[]
+					out.numlines = cs.getInt(2)
+					return out
+				}
+			})
+			for (i : 0 ..< ret.numlines) {
+				val line = ret.lines.get(i)
+				if (line !== null) {
+					sb.append(ret.lines.get(i))
+				}
+				sb.append(System.lineSeparator)
+			}
+		} while (ret.numlines > 0)
+		return sb.toString
+	}	
+	
+	def String htmlCodeCoverage(List<String> pathList) {
+		enableDbmsOutput
+		val sql = '''
+			BEGIN
+				ut.run(
+					ut_varchar2_list(
+						«FOR path : pathList SEPARATOR ","»
+							'«path»'
+						«ENDFOR»
+					),
+					ut_coverage_html_reporter()
+				);
+			END;
+		'''
+		jdbcTemplate.update(sql)
+		val ret = getDbmsOutput
+		disableDbmsOutput
+		return ret
+	} 
 
 }
diff --git a/sqldev/src/test/java/org/utplsql/sqldev/tests/DalTest.xtend b/sqldev/src/test/java/org/utplsql/sqldev/tests/DalTest.xtend
@@ -294,4 +294,37 @@ class DalTest extends AbstractJdbcTest {
 		Assert.assertEquals("SCOTT:a.b.c.JUNIT_UTPLSQL_TEST_PKG.mycontext", effective.get("SCOTT:a.b.c.JUNIT_UTPLSQL_TEST_PKG.mycontext.t2"))
 	}
 
+	@Test
+	def void dbmsOutput() {
+		val dao = new UtplsqlDao(dataSource.connection)
+		dao.enableDbmsOutput
+		jdbcTemplate.execute('''
+			BEGIN
+			   sys.dbms_output.put_line('line1');
+			   sys.dbms_output.put_line('line2');
+			   sys.dbms_output.put_line(null);
+			   sys.dbms_output.put_line('line4');
+			   sys.dbms_output.put_line('line5');
+			END;
+		''')
+		val effective = dao.getDbmsOutput(2)
+		val expected = '''
+			line1
+			line2
+
+			line4
+			line5
+		'''
+		Assert.assertEquals(expected, effective)
+	}
+	
+	@Test
+	def void htmlCodeCoverage() {
+		setupAndTeardown
+		val dao = new UtplsqlDao(dataSource.connection)
+		val effective = dao.htmlCodeCoverage(#["SCOTT"])
+		Assert.assertTrue(effective.startsWith("<!DOCTYPE html>"))
+		Assert.assertTrue(effective.trim.endsWith("</html>"))
+	}
+
 }
