Базовый модуль утверждений (assertions) из фреймворка xUnitFor1C

Author: EvilBeaver

Утверждения.os

@@ -0,0 +1,110 @@
+Процедура Проверить(Условие, ДопСообщениеОшибки = "") Экспорт
+	Если Не Условие Тогда
+		СообщениеОшибки = "Переданный параметр ("+Формат(Условие, "БЛ=ложь; БИ=истина")+") не является Истиной, а хотели, чтобы являлся." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение(СообщениеОшибки);
+	КонецЕсли;
+КонецПроцедуры
+
+Процедура ПроверитьИстину(Условие, ДопСообщениеОшибки = "") Экспорт
+	Проверить(Условие, ДопСообщениеОшибки);
+КонецПроцедуры
+
+Процедура ПроверитьЛожь(Условие, ДопСообщениеОшибки = "") Экспорт
+	Если Условие Тогда
+		СообщениеОшибки = "Переданный параметр ("+Формат(Условие, "БЛ=ложь; БИ=истина")+") не является Ложью, а хотели, чтобы являлся." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение(СообщениеОшибки);
+	КонецЕсли;
+КонецПроцедуры
+
+Процедура ПроверитьДату(_Дата, _Период, ДопСообщениеОшибки = "") Экспорт
+	Если _Дата < _Период.ДатаНачала или _Дата > _Период.ДатаОкончания Тогда
+		представление = ПредставлениеПериода(_Период.ДатаНачала, _Период.ДатаОкончания, "ФП = Истина");
+		СообщениеОшибки = "Переданный параметр ("+Формат(_Дата, "ДФ='dd.MM.yyyy HH:mm:ss'")+") не входит в период "+представление+", а хотели, чтобы являлся." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение(СообщениеОшибки);
+	КонецЕсли;
+КонецПроцедуры
+
+Процедура ПроверитьРавенство(ПервоеЗначение, ВтороеЗначение, ДопСообщениеОшибки = "") Экспорт
+	Если ПервоеЗначение <> ВтороеЗначение Тогда
+		СообщениеОшибки = "Сравниваемые значения ("+ПервоеЗначение+"; "+ВтороеЗначение+") не равны, а хотели, чтобы были равны." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение(СообщениеОшибки);
+	КонецЕсли;
+КонецПроцедуры
+
+Процедура ПроверитьНеРавенство(ПервоеЗначение, ВтороеЗначение, ДопСообщениеОшибки = "") Экспорт
+	Если ПервоеЗначение = ВтороеЗначение Тогда
+		СообщениеОшибки = "Сравниваемые значения ("+ПервоеЗначение+"; "+ВтороеЗначение+") равны, а хотели, чтобы были не равны." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение(СообщениеОшибки);
+	КонецЕсли;
+КонецПроцедуры
+
+Процедура ПроверитьБольше(_Больше, _Меньше, ДопСообщениеОшибки = "") Экспорт
+	Если _Больше <= _Меньше Тогда
+		СообщениеОшибки = "Первый параметр ("+_Больше+") меньше или равен второму ("+_Меньше+") а хотели, чтобы был больше." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение(СообщениеОшибки);
+	КонецЕсли;
+КонецПроцедуры
+
+Процедура ПроверитьБольшеИлиРавно(_Больше, _Меньше, ДопСообщениеОшибки = "") Экспорт
+	Если _Больше < _Меньше Тогда
+		СообщениеОшибки = "Первый параметр ("+_Больше+") меньше второго ("+_Меньше+") а хотели, чтобы был больше или равен." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение(СообщениеОшибки);
+	КонецЕсли;
+КонецПроцедуры
+
+Процедура ПроверитьМеньше(проверяемоеЗначение1, проверяемоеЗначение2, СообщениеОбОшибке = "") Экспорт
+	Если проверяемоеЗначение1 >= проверяемоеЗначение2 Тогда
+		ВызватьИсключение "Значение <"+проверяемоеЗначение1+"> больше или равно, чем <"+проверяемоеЗначение2+">, а ожидалось меньше"+
+				ФорматДСО(СообщениеОбОшибке);
+	КонецЕсли; 
+КонецПроцедуры
+
+Процедура ПроверитьМеньшеИлиРавно(проверяемоеЗначение1, проверяемоеЗначение2, СообщениеОбОшибке = "") Экспорт
+	Если проверяемоеЗначение1 > проверяемоеЗначение2 Тогда
+		ВызватьИсключение "Значение <"+проверяемоеЗначение1+"> больше, чем <"+проверяемоеЗначение2+">, а ожидалось меньше или равно"+
+				ФорматДСО(СообщениеОбОшибке);
+	КонецЕсли; 
+КонецПроцедуры
+
+// проверка идет через ЗначениеЗаполнено, но мутабельные значение всегда считаем заполненными
+Процедура ПроверитьЗаполненность(ПроверяемоеЗначение, ДопСообщениеОшибки = "") Экспорт
+    Попытка
+        фЗаполнено = ЗначениеЗаполнено(ПроверяемоеЗначение);
+    Исключение
+        Возврат;
+    КонецПопытки; 
+    Если НЕ фЗаполнено Тогда
+        ВызватьИсключение "Значение ("+ПроверяемоеЗначение+") не заполнено, а ожидалась заполненность" + ФорматДСО(ДопСообщениеОшибки);
+    КонецЕсли; 
+КонецПроцедуры
+
+Процедура ПроверитьНеЗаполненность(ПроверяемоеЗначение, ДопСообщениеОшибки = "") Экспорт
+	СообщениеОшибки = "Значение ("+ПроверяемоеЗначение+") заполнено, а ожидалась незаполненность" + ФорматДСО(ДопСообщениеОшибки);
+	Попытка
+        фЗаполнено = ЗначениеЗаполнено(ПроверяемоеЗначение);
+    Исключение
+        ВызватьИсключение СообщениеОшибки;
+    КонецПопытки; 
+    Если фЗаполнено Тогда
+        ВызватьИсключение СообщениеОшибки;
+    КонецЕсли; 
+КонецПроцедуры
+
+Процедура ПроверитьВхождение(строка, подстрокаПоиска, ДопСообщениеОшибки = "") Экспорт
+	Если Найти(строка, подстрокаПоиска) = 0 Тогда
+		СообщениеОшибки = "Искали в <"+строка+"> подстроку <"+подстрокаПоиска+">, но не нашли." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение(СообщениеОшибки);
+	КонецЕсли;
+КонецПроцедуры
+
+Функция ФорматДСО(ДопСообщениеОшибки)
+	Если ДопСообщениеОшибки = "" Тогда
+		Возврат "";
+	КонецЕсли;
+	
+	Возврат Символы.ПС + ДопСообщениеОшибки;
+КонецФункции
+
+Функция ПредставлениеПериода(ДатаНачала, ДатаОкончания, ФорматнаяСтрока = Неопределено)
+	Возврат "с "+ДатаНачала+" по "+ДатаОкончания;
+КонецФункции