Добавлены утверждения в стиле BDD

Author: wizi4d

lib.config

@@ -1,3 +1,4 @@
 <package-def>
 	<module name="Утверждения" file="src/xunit-legacy.os"/>
+	<module name="Ожидаем" file="src/bdd-asserts.os"/>
 </package-def>

src/bdd-asserts.os

@@ -0,0 +1,235 @@
+Перем ПроверяемоеЗначение;
+Перем ДопСообщениеОшибки;
+Перем ФлагОтрицания;
+Перем СтатусыРезультатаТестирования;
+
+Функция Что(ПроверяемоеЗначениеПараметр, Сообщение = "") Экспорт
+	ПроверяемоеЗначение = ПроверяемоеЗначениеПараметр;
+	ДопСообщениеОшибки = Сообщение;
+	ФлагОтрицания = Ложь;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция Не_() Экспорт
+	ФлагОтрицания = Истина;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция ЭтоИстина() Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(Формат(ПроверяемоеЗначение, "БЛ=Ложь; БИ=Истина"), "является ИСТИНОЙ.");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция ЭтоЛожь() Экспорт
+	Если Не ЛогическоеВыражениеВерно(Не ПроверяемоеЗначение) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(Формат(ПроверяемоеЗначение, "БЛ=Ложь; БИ=Истина"), "является ЛОЖЬЮ.");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция Равно(ОжидаемоеЗначение) Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение = ОжидаемоеЗначение) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "РАВНО (" + ОжидаемоеЗначение + ").");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция Больше(МеньшееЗначение) Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение > МеньшееЗначение) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "БОЛЬШЕ (" + МеньшееЗначение + ").");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция БольшеИлиРавно(МеньшееИлиРавноеЗначение) Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение >= МеньшееИлиРавноеЗначение) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "БОЛЬШЕ ИЛИ РАВНО (" + МеньшееИлиРавноеЗначение + ").");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция Минимум(МинимальноеЗначение) Экспорт
+	Возврат БольшеИлиРавно(МинимальноеЗначение);
+КонецФункции
+
+Функция МеньшеИлиРавно(БольшееИлиРавноеЗначение) Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение <= БольшееИлиРавноеЗначение) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "МЕНЬШЕ ИЛИ РАВНО (" + БольшееИлиРавноеЗначение + ").");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция Максимум(МаксимальноеЗначение) Экспорт
+	Возврат МеньшеИлиРавно(МаксимальноеЗначение);
+КонецФункции
+
+Функция Меньше(БольшееЗначение) Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение < БольшееЗначение) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "МЕНЬШЕ (" + БольшееЗначение + ").");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция Заполнено() Экспорт
+	Если Не ЛогическоеВыражениеВерно(ЗначениеЗаполнено(ПроверяемоеЗначение)) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "является ЗАПОЛНЕННЫМ.");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция Существует() Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение <> Неопределено И ПроверяемоеЗначение <> Null) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "СУЩЕСТВУЕТ.");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция ЭтоНеопределено() Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение = Неопределено) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "является НЕОПРЕДЕЛЕНО.");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция ЭтоNull() Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение = Null) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "является NULL.");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция ИмеетТип(ТипИлиИмяТипа) Экспорт
+	ОжидаемыйТип = ?(ТипЗнч(ТипИлиИмяТипа) = Тип("Строка"), Тип(ТипИлиИмяТипа), ТипИлиИмяТипа);
+	ТипПроверяемогоЗначения = ТипЗнч(ПроверяемоеЗначение);
+	Если Не ЛогическоеВыражениеВерно(ТипПроверяемогоЗначения = ОжидаемыйТип) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке("тип - " + ТипПроверяемогоЗначения, "имеет тип (" + ОжидаемыйТип + ").");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция Между(НачальноеЗначение, КонечноеЗначение) Экспорт
+	Если Не ЛогическоеВыражениеВерно(ПроверяемоеЗначение >= НачальноеЗначение И ПроверяемоеЗначение <= КонечноеЗначение) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "МЕЖДУ (" + НачальноеЗначение + ") и (" + КонечноеЗначение + ").");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция Содержит(ИскомоеЗначение) Экспорт
+	Перем ИскомоеЗначениеНайдено;
+	
+	ТипПроверяемоегоЗначения = ТипЗнч(ПроверяемоеЗначение);
+	Если ТипПроверяемоегоЗначения = Тип("Строка") Тогда
+		ИскомоеЗначениеНайдено = Найти(ПроверяемоеЗначение, ИскомоеЗначение) > 0;
+	ИначеЕсли ТипПроверяемоегоЗначения = Тип("Массив") Или ТипПроверяемоегоЗначения = Тип("ФиксированныйМассив") Тогда
+		ИскомоеЗначениеНайдено = ПроверяемоеЗначение.Найти(ИскомоеЗначение) <> Неопределено;
+	ИначеЕсли ТипПроверяемоегоЗначения = Тип("Структура") Или ТипПроверяемоегоЗначения = Тип("ФиксированнаяСтруктура")
+			Или ТипПроверяемоегоЗначения = Тип("Соответствие") Или ТипПроверяемоегоЗначения = Тип("ФиксированноеСоответствие") Тогда
+		Для каждого КлючЗначение Из ПроверяемоеЗначение Цикл
+			ИскомоеЗначениеНайдено = КлючЗначение.Значение = ИскомоеЗначение;
+			Если ИскомоеЗначениеНайдено Тогда
+				Прервать;
+			КонецЕсли;
+		КонецЦикла;
+	ИначеЕсли ТипПроверяемоегоЗначения = Тип("СписокЗначений") Тогда
+		ИскомоеЗначениеНайдено = ПроверяемоеЗначение.НайтиПоЗначению(ИскомоеЗначение) <> Неопределено;
+	КонецЕсли;
+	
+	Если ИскомоеЗначениеНайдено = Неопределено Тогда
+		СообщениеОшибки = "Утверждение ""Содержит"" не умеет работать с типом <" + ТипПроверяемоегоЗначения + ">." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение СообщениеОшибки;
+	КонецЕсли;
+	
+	Если Не ЛогическоеВыражениеВерно(ИскомоеЗначениеНайдено) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, "СОДЕРЖИТ (" + ИскомоеЗначение + ").");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+Функция ИмеетДлину(ОжидаемаяДлина) Экспорт
+	Перем ФактическаяДлина;
+	
+	ТипПроверяемоегоЗначения = ТипЗнч(ПроверяемоеЗначение);
+	Если ТипПроверяемоегоЗначения = Тип("Строка") Тогда
+		ФактическаяДлина = СтрДлина(ПроверяемоеЗначение);
+	ИначеЕсли ТипПроверяемоегоЗначения = Тип("Массив") Или ТипПроверяемоегоЗначения = Тип("ФиксированныйМассив")
+			Или ТипПроверяемоегоЗначения = Тип("Структура") Или ТипПроверяемоегоЗначения = Тип("ФиксированнаяСтруктура")
+			Или ТипПроверяемоегоЗначения = Тип("Соответствие") Или ТипПроверяемоегоЗначения = Тип("ФиксированноеСоответствие")
+			Или ТипПроверяемоегоЗначения = Тип("СписокЗначений") Тогда
+		ФактическаяДлина = ПроверяемоеЗначение.Количество();
+	КонецЕсли;
+	
+	Если ФактическаяДлина = Неопределено Тогда
+		СообщениеОшибки = "Утверждение ""ИмеетДлину"" не умеет работать с типом <" + ТипПроверяемоегоЗначения + ">." + ФорматДСО(ДопСообщениеОшибки);
+		ВызватьИсключение СообщениеОшибки;
+	КонецЕсли;
+	
+	Если Не ЛогическоеВыражениеВерно(ФактическаяДлина = ОжидаемаяДлина) Тогда
+		СообщениеОшибки = СформироватьСообщениеОбОшибке("<" +ПроверяемоеЗначение + "> с длиной " + ФактическаяДлина, "ИМЕЕТ ДЛИНУ (" + ОжидаемаяДлина + ").");
+		ВызватьОшибкуПроверки(СообщениеОшибки);
+	КонецЕсли;
+	
+	Возврат ЭтотОбъект;
+КонецФункции
+
+// { Helpers
+Функция ФорматДСО(ДопСообщениеОшибки)
+	Если ДопСообщениеОшибки = "" Тогда
+		Возврат "";
+	КонецЕсли;
+	
+	Возврат Символы.ПС + ДопСообщениеОшибки;
+КонецФункции
+
+Процедура ВызватьОшибкуПроверки(СообщениеОшибки)
+	Префикс = "["+ СтатусыРезультатаТестирования.ОшибкаПроверки + "]";
+	ВызватьИсключение Префикс + " " + СообщениеОшибки;
+КонецПроцедуры
+
+Функция ЛогическоеВыражениеВерно(ЛогическоеВыражение)
+	Результат = ФлагОтрицания <> ЛогическоеВыражение;
+	ФлагОтрицания = Ложь;
+	
+	Возврат Результат;
+КонецФункции
+
+Функция СформироватьСообщениеОбОшибке(ПроверяемоеЗначение, Ожидание)
+	Возврат "Ожидали, что проверяемое значение (" + ПроверяемоеЗначение + ")" + ?(ФлагОтрицания, " НЕ ", " ") + Ожидание + ФорматДСО(ДопСообщениеОшибки);
+КонецФункции
+// } Helpers
+
+СтатусыРезультатаТестирования = Новый Структура;
+СтатусыРезультатаТестирования.Вставить("ОшибкаПроверки", "Failed");
+СтатусыРезультатаТестирования.Вставить("НеизвестнаяОшибка", "Broken");
+СтатусыРезультатаТестирования.Вставить("ТестПропущен", "Pending");