Исправил ошибку: Библиотека asserts не тестируется через 1testrunner #3

Добавил универсальный файл прогона тестов и фич

Author: artbear

.gitignore

@@ -0,0 +1,3 @@
+oscript_modules/
+
+tests\.xml

tasks/test.os

@@ -0,0 +1,92 @@
+#Использовать ".."
+#Использовать 1bdd
+#Использовать 1testrunner
+
+Функция ПрогнатьТесты()
+	
+	Тестер = Новый Тестер;
+
+	ПутьКТестам = ОбъединитьПути(ТекущийСценарий().Каталог, "..", "tests");
+	
+	Файл_ПутьКТестам = Новый Файл(ПутьКТестам);
+	Если Не Файл_ПутьКТестам.Существует() Тогда
+		Возврат Истина;
+	КонецЕсли;
+	
+	ПутьКОтчетуJUnit = ОбъединитьПути(ТекущийСценарий().Каталог, "..");
+
+	РезультатТестирования = Тестер.ТестироватьКаталог(
+		Новый Файл(ПутьКТестам),
+		Новый Файл(ПутьКОтчетуJUnit)
+	);
+
+	Успешно = РезультатТестирования = 0;
+	
+	Возврат Успешно;
+КонецФункции // ПрогнатьТесты()
+
+Функция ПрогнатьФичи()
+	
+	ПутьОтчетаJUnit = "./bdd-log.xml";
+
+	КаталогФич = ОбъединитьПути(ТекущийСценарий().Каталог, ".", "features");
+
+	ИсполнительБДД = Новый ИсполнительБДД;
+
+	Файл_КаталогФич = Новый Файл(КаталогФич);
+	Если Не Файл_КаталогФич.Существует() Тогда
+		Возврат ИсполнительБДД.ВозможныеСтатусыВыполнения().Пройден;
+	КонецЕсли;
+
+	РезультатыВыполнения = ИсполнительБДД.ВыполнитьФичу(Файл_КаталогФич, Файл_КаталогФич);
+	ИтоговыйРезультатВыполнения = ИсполнительБДД.ПолучитьИтоговыйСтатусВыполнения(РезультатыВыполнения);
+
+	СтатусВыполнения = ИсполнительБДД.ВозможныеСтатусыВыполнения().НеВыполнялся;
+	Если РезультатыВыполнения.Строки.Количество() > 0 Тогда
+		
+		СтатусВыполнения = ИсполнительБДД.ПолучитьИтоговыйСтатусВыполнения(РезультатыВыполнения);
+		
+	КонецЕсли;
+
+	ГенераторОтчетаJUnit = Новый ГенераторОтчетаJUnit;
+	ГенераторОтчетаJUnit.Сформировать(РезультатыВыполнения, СтатусВыполнения, ПутьОтчетаJUnit);
+
+	Сообщить(СтрШаблон("Результат прогона фич <%1>
+	|", ИтоговыйРезультатВыполнения));
+
+	Возврат ИтоговыйРезультатВыполнения <> ИсполнительБДД.ВозможныеСтатусыВыполнения().Сломался;
+КонецФункции // ПрогнатьФичи()
+
+Попытка
+	ТестыПрошли = ПрогнатьТесты();
+
+Исключение
+	ТестыПрошли = Ложь;
+	Сообщить(СтрШаблон("Тесты через 1testrunner выполнены неудачно
+	|%1", ПодробноеПредставлениеОшибки(ИнформацияОбОшибке())));
+КонецПопытки;
+
+Попытка
+	ФичиПрошли = ПрогнатьФичи();
+Исключение
+	ФичиПрошли = Ложь;
+	Сообщить(СтрШаблон("Тесты поведения через 1bdd выполнены неудачно
+	|%1", ПодробноеПредставлениеОшибки(ИнформацияОбОшибке())));
+КонецПопытки;
+
+Если Не ТестыПрошли Или Не ФичиПрошли Тогда
+	ВызватьИсключение "Тестирование завершилось неудачно!";
+Иначе
+	Сообщить(СтрШаблон("Результат прогона тестов <%1>
+	|", ТестыПрошли));
+КонецЕсли;
+
+	// Если РезультатТестирования <> 0 Тогда
+	// 	ВызватьИсключение РезультатТестирования;
+	// КонецЕсли;
+
+	// Если ИтоговыйРезультатВыполнения = ИсполнительБДД.ВозможныеСтатусыВыполнения().Сломался Тогда
+		
+	// 	ВызватьИсключение 1;
+		
+	// КонецЕсли;