Fix output directory handling with $<CONFIG> (corrosion-rs#631)

* Fixes output directory handling for generator expressions

Ensures that the configuration subdirectory is only appended to the output directory if the specified output directory does not already contain a generator expression. This mirrors the logic from _corrosion_set_imported_location_deferred. This prevents incorrect path construction when generator expressions are used to define output paths.

* Add Test for $<CONFIG> in output directory

* Fix $<CONFIG> in single-config generators

---------

Co-authored-by: Jonathan Schwender <schwenderjonathan@gmail.com>

Author: narknon

cmake/Corrosion.cmake

@@ -114,6 +114,26 @@ function(_corrosion_bin_target_suffix target_name out_var_suffix)
     set(${out_var_suffix} "${_suffix}" PARENT_SCOPE)
 endfunction()
 
+function(_handle_output_directory_genex input_path config_type output_path)
+    if("${config_type}" STREQUAL "")
+        # Prevent new path from being `dir//file`, since that causes issues with the
+        # file dependency.
+        string(REPLACE "/\$<CONFIG>" "${config_type}" curr_out_dir "${input_path}")
+        string(REPLACE "\$<CONFIG>" "${config_type}" curr_out_dir "${curr_out_dir}")
+    else()
+        string(REPLACE "\$<CONFIG>" "${config_type}" curr_out_dir "${input_path}")
+    endif()
+    string(GENEX_STRIP "${curr_out_dir}" stripped_out_dir)
+    if("${stripped_out_dir}" STREQUAL "${curr_out_dir}")
+        set("${output_path}" "${curr_out_dir}" PARENT_SCOPE)
+    else()
+        unset("${output_path}" PARENT_SCOPE)
+        message(WARNING "Encountered output directory path with unsupported genex. "
+                "Output dir: `${curr_out_dir}`"
+                "Note: Corrosion only supports the `\$<CONFIG>` generator expression for output directories.")
+    endif()
+endfunction()
+
 # Do not call this function directly!
 #
 # This function should be called deferred to evaluate target properties late in the configure stage.
@@ -159,12 +179,8 @@ function(_corrosion_set_imported_location_deferred target_name base_property out
         else()
             set(curr_out_dir "${CMAKE_CURRENT_BINARY_DIR}")
         endif()
-        string(REPLACE "\$<CONFIG>" "${config_type}" curr_out_dir "${curr_out_dir}")
-        message(DEBUG "Setting ${base_property}_${config_type_upper} for target ${target_name}"
-                " to `${curr_out_dir}/${filename}`.")
-
-        string(GENEX_STRIP "${curr_out_dir}" stripped_out_dir)
-        if(NOT ("${stripped_out_dir}" STREQUAL "${curr_out_dir}"))
+        _handle_output_directory_genex("${curr_out_dir}" "${config_type}" sanitized_out_dir)
+        if(NOT DEFINED sanitized_out_dir)
             message(FATAL_ERROR "${output_directory_property} for target ${output_dir_prop_target_name} "
                     "contained an unexpected Generator expression. Output dir: `${curr_out_dir}`"
                 "Note: Corrosion only supports the `\$<CONFIG>` generator expression for output directories.")
@@ -174,9 +190,9 @@ function(_corrosion_set_imported_location_deferred target_name base_property out
         set_property(
             TARGET ${target_name}
             PROPERTY "${base_property}_${config_type_upper}"
-                "${curr_out_dir}/${filename}"
+                "${sanitized_out_dir}/${filename}"
         )
-        set(base_output_directory "${curr_out_dir}")
+        set(base_output_directory "${sanitized_out_dir}")
     endforeach()
 
     if(NOT COR_IS_MULTI_CONFIG)
@@ -185,13 +201,13 @@ function(_corrosion_set_imported_location_deferred target_name base_property out
         else()
             set(base_output_directory "${CMAKE_CURRENT_BINARY_DIR}")
         endif()
-        string(REPLACE "\$<CONFIG>" "${CMAKE_BUILD_TYPE}" base_output_directory "${base_output_directory}")
-        string(GENEX_STRIP "${base_output_directory}" stripped_out_dir)
-        if(NOT ("${stripped_out_dir}" STREQUAL "${base_output_directory}"))
+        _handle_output_directory_genex("${base_output_directory}" "${CMAKE_BUILD_TYPE}" sanitized_output_directory)
+        if(NOT DEFINED sanitized_output_directory)
             message(FATAL_ERROR "${output_dir_prop_target_name} for target ${output_dir_prop_target_name} "
-                    "contained an unexpected Generator expression. Output dir: `${base_output_directory}`"
+                    "contained an unexpected Generator expression. Output dir: `${base_output_directory}`."
                     "Note: Corrosion only supports the `\$<CONFIG>` generator expression for output directories.")
         endif()
+        set(base_output_directory "${sanitized_output_directory}")
     endif()
 
     message(DEBUG "Setting ${base_property} for target ${target_name}"
@@ -259,10 +275,15 @@ function(_corrosion_copy_byproduct_deferred target_name output_dir_prop_names ca
         if(output_dir_curr_config)
             set(curr_out_dir "${output_dir_curr_config}")
         elseif(output_dir)
-            # Fallback to `output_dir` if specified
-            # Note: Multi-configuration generators append a per-configuration subdirectory to the
-            # specified directory unless a generator expression is used (from CMake documentation).
-            set(curr_out_dir "${output_dir}/${config_type}")
+            string(GENEX_STRIP "${output_dir}" output_dir_no_genex)
+            # Only add config dir if there is no genex in here. See
+            # https://cmake.org/cmake/help/latest/prop_tgt/RUNTIME_OUTPUT_DIRECTORY.html
+            # Logic duplicated from _corrosion_set_imported_location_deferred
+            if(output_dir STREQUAL output_dir_no_genex)
+                set(curr_out_dir "${output_dir}/${config_type}")
+            else()
+                set(curr_out_dir "${output_dir}")
+            endif()
         else()
             # Fallback to the default directory. We do not append the configuration directory here
             # and instead let CMake do this, since otherwise the resolving of dynamic library

test/output directory/CMakeLists.txt

@@ -32,7 +32,6 @@ add_test(NAME "output_directory_build"
         CARGO_TARGET "${Rust_CARGO_TARGET}"
         SYSTEM_NAME "${CMAKE_SYSTEM_NAME}"
         ${configure_cmake_args}
-
         COMMAND_EXPAND_LISTS
 )
 set_tests_properties("output_directory_build" PROPERTIES FIXTURES_SETUP "build_fixture_output_directory")
@@ -159,4 +158,14 @@ set_tests_properties("postbuild_custom_command" PROPERTIES FIXTURES_REQUIRED "bu
 add_test(NAME "output_directory_cleanup" COMMAND "${CMAKE_COMMAND}" -E remove_directory "${CMAKE_CURRENT_BINARY_DIR}/build")
 set_tests_properties("output_directory_cleanup" PROPERTIES FIXTURES_CLEANUP "build_fixture_output_directory")
 
+####################################
+# output_directory_config
+####################################
+
+
+ corrosion_tests_add_test(output_directory_config "consumer")
+
+ set_tests_properties("output_directory_config_run_consumer" PROPERTIES PASS_REGULAR_EXPRESSION
+         "^Hello from output_directory_config_test_executable"
+    )
 

test/output directory/output_directory_config/CMakeLists.txt

@@ -0,0 +1,23 @@
+cmake_minimum_required(VERSION 3.15)
+project(test_project VERSION 0.1.0)
+include(../../test_header.cmake)
+
+corrosion_import_crate(MANIFEST_PATH proj1/Cargo.toml)
+
+# Note: The output directories defined here must be manually kept in sync with the expected test location.
+set_target_properties(rust_bin1
+    PROPERTIES
+        RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/bin"
+        PDB_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/bin"
+)
+
+set_target_properties(rust_lib1 PROPERTIES ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/lib")
+set_target_properties(rust_lib1
+                      PROPERTIES
+                      LIBRARY_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/lib"
+                      PDB_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/lib"
+)
+
+add_executable(consumer consumer.cpp)
+add_dependencies(consumer cargo-build_rust_lib1)
+target_link_libraries(consumer rust_lib1)

test/output directory/output_directory_config/consumer.cpp

@@ -0,0 +1,16 @@
+#include <iostream>
+#include <cstdlib>
+
+extern "C" unsigned int ret_12();
+
+
+int main(int argc, char *argv[])
+{
+    std::cout << "Hello from output_directory_config_test_executable\n";
+    unsigned int a = ret_12();
+    if (a != 12) {
+        return -1;
+    }
+
+    return 0;
+}

test/output directory/output_directory_config/proj1/Cargo.lock

@@ -0,0 +1,11 @@
+[package]
+name = "rust_package1"
+version = "0.1.0"
+edition = "2018"
+
+[lib]
+name = "rust_lib1"
+crate-type=["staticlib", "cdylib"]
+
+[[bin]]
+name = "rust_bin1"

test/output directory/output_directory_config/proj1/Cargo.toml

@@ -0,0 +1,3 @@
+fn main() {
+    println!("Hello, world from test rust binary");
+}

test/output directory/output_directory_config/proj1/src/bin/rust_bin1.rs

@@ -0,0 +1,4 @@
+#[no_mangle]
+pub extern "C" fn ret_12() -> u32 {
+    12
+}