C#: Re-factor telemetry queries to avoid code duplication.

Author: michaelnebel

csharp/ql/src/Telemetry/ExternalApi.qll

@@ -114,19 +114,28 @@ class ExternalApi extends DotNet::Callable {
 int resultLimit() { result = 1000 }
 
 /**
- * Holds if the relevant usage count of api with `apiInfo` is `usages`.
+ * Holds if it is relevant to count usages of `api`.
  */
-signature predicate relevantUsagesSig(string apiInfo, int usages);
+signature predicate relevantApi(ExternalApi api);
 
 /**
  * Given a predicate to count relevant API usages, this module provides a predicate
  * for restricting the number or returned results based on a certain limit.
  */
-module Results<relevantUsagesSig/2 getRelevantUsages> {
+module Results<relevantApi/1 getRelevantUsages> {
+  private int getUsages(string apiInfo) {
+    result =
+      strictcount(DispatchCall c, ExternalApi api |
+        c = api.getACall() and
+        apiInfo = api.getInfo() and
+        getRelevantUsages(api)
+      )
+  }
+
   private int getOrder(string apiInfo) {
     apiInfo =
       rank[result](string info, int usages |
-        getRelevantUsages(info, usages)
+        usages = getUsages(info)
       |
         info order by usages desc, info
       )
@@ -137,6 +146,7 @@ module Results<relevantUsagesSig/2 getRelevantUsages> {
    * and if it is in the top results (guarded by resultLimit).
    */
   predicate restrict(string apiInfo, int usages) {
-    getRelevantUsages(apiInfo, usages) and getOrder(apiInfo) <= resultLimit()
+    usages = getUsages(apiInfo) and
+    getOrder(apiInfo) <= resultLimit()
   }
 }

csharp/ql/src/Telemetry/SupportedExternalSinks.ql

@@ -10,16 +10,11 @@ private import csharp
 private import semmle.code.csharp.dispatch.Dispatch
 private import ExternalApi
 
-private predicate getRelevantUsages(string apiInfo, int usages) {
-  usages =
-    strictcount(DispatchCall c, ExternalApi api |
-      apiInfo = api.getInfo() and
-      c = api.getACall() and
-      not api.isUninteresting() and
-      api.isSink()
-    )
+private predicate relevant(ExternalApi api) {
+  not api.isUninteresting() and
+  api.isSink()
 }
 
 from string info, int usages
-where Results<getRelevantUsages/2>::restrict(info, usages)
+where Results<relevant/1>::restrict(info, usages)
 select info, usages order by usages desc

csharp/ql/src/Telemetry/SupportedExternalSources.ql

@@ -10,16 +10,11 @@ private import csharp
 private import semmle.code.csharp.dispatch.Dispatch
 private import ExternalApi
 
-private predicate getRelevantUsages(string apiInfo, int usages) {
-  usages =
-    strictcount(DispatchCall c, ExternalApi api |
-      c = api.getACall() and
-      apiInfo = api.getInfo() and
-      not api.isUninteresting() and
-      api.isSource()
-    )
+private predicate relevant(ExternalApi api) {
+  not api.isUninteresting() and
+  api.isSource()
 }
 
 from string info, int usages
-where Results<getRelevantUsages/2>::restrict(info, usages)
+where Results<relevant/1>::restrict(info, usages)
 select info, usages order by usages desc

csharp/ql/src/Telemetry/SupportedExternalTaint.ql

@@ -10,16 +10,11 @@ private import csharp
 private import semmle.code.csharp.dispatch.Dispatch
 private import ExternalApi
 
-private predicate getRelevantUsages(string apiInfo, int usages) {
-  usages =
-    strictcount(DispatchCall c, ExternalApi api |
-      apiInfo = api.getInfo() and
-      c = api.getACall() and
-      not api.isUninteresting() and
-      api.hasSummary()
-    )
+private predicate relevant(ExternalApi api) {
+  not api.isUninteresting() and
+  api.hasSummary()
 }
 
 from string info, int usages
-where Results<getRelevantUsages/2>::restrict(info, usages)
+where Results<relevant/1>::restrict(info, usages)
 select info, usages order by usages desc

csharp/ql/src/Telemetry/UnsupportedExternalAPIs.ql

@@ -12,17 +12,12 @@ private import semmle.code.csharp.dataflow.internal.FlowSummaryImpl as FlowSumma
 private import semmle.code.csharp.dataflow.internal.NegativeSummary
 private import ExternalApi
 
-private predicate getRelevantUsages(string apiInfo, int usages) {
-  usages =
-    strictcount(DispatchCall c, ExternalApi api |
-      apiInfo = api.getInfo() and
-      c = api.getACall() and
-      not api.isUninteresting() and
-      not api.isSupported() and
-      not api instanceof FlowSummaryImpl::Public::NegativeSummarizedCallable
-    )
+private predicate relevant(ExternalApi api) {
+  not api.isUninteresting() and
+  not api.isSupported() and
+  not api instanceof FlowSummaryImpl::Public::NegativeSummarizedCallable
 }
 
 from string info, int usages
-where Results<getRelevantUsages/2>::restrict(info, usages)
+where Results<relevant/1>::restrict(info, usages)
 select info, usages order by usages desc