Add initial test logic for the open source build

Adds logic to pull in googletest as a dependency, and the basic framework for defining "cc_tests" that have sources and dependencies.

PiperOrigin-RevId: 253827317

Author: a-maurice

CMakeLists.txt

@@ -37,10 +37,20 @@ option(FIREBASE_INCLUDE_REMOTE_CONFIG
        "Include the Firebase Remote Config library." ON)
 option(FIREBASE_INCLUDE_STORAGE
        "Include the Cloud Storage for Firebase library." ON)
+option(FIREBASE_CPP_BUILD_TESTS
+       "Enable the Firebase C++ Build Tests." OFF)
 
 list(INSERT CMAKE_MODULE_PATH 0 ${CMAKE_CURRENT_LIST_DIR}/cmake)
 include(external_rules)
 
+if(FIREBASE_CPP_BUILD_TESTS)
+  enable_testing()
+  include(test_rules)
+  # Copy the custom CTest file into the binary directory, so that it is used.
+  configure_file(${CMAKE_CURRENT_LIST_DIR}/cmake/CTestCustom.cmake
+               ${CMAKE_BINARY_DIR})
+endif()
+
 # Occasionally ANDROID is not being set correctly when invoked by gradle, so
 # set it manually if ANDROID_NDK has been defined.
 if(DEFINED ANDROID_NDK)
@@ -90,6 +100,10 @@ set(FLATBUFFERS_BUILD_TESTS OFF CACHE BOOL "")
 # so that the sub Firebase projects can depend upon it if necessary.
 add_external_library(flatbuffers)
 
+if(FIREBASE_CPP_BUILD_TESTS)
+  add_external_library(googletest)
+endif()
+
 # Some of the external libraries are not used for mobile.
 if (NOT ANDROID AND NOT IOS)
   # Build curl as a static library

cmake/CTestCustom.cmake

@@ -0,0 +1,24 @@
+# Copyright 2019 Google
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+# Define the tests that need to be ignored.
+set(CTEST_CUSTOM_TESTS_IGNORE
+    ${CTEST_CUSTOM_TESTS_IGNORE}
+    # Tests from libuv, that can't be disabled normally.
+    uv_test
+    uv_test_a
+    # Tests from zlib, that can't be disabled normally.
+    example
+    example64
+)

cmake/external/CMakeLists.txt

@@ -23,6 +23,7 @@ project(Firebase-cpp-download C CXX)
 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
 
 include(flatbuffers)
+include(googletest)
 
 # Some of the external dependencies are not needed for mobile.
 if (${FIREBASE_EXTERNAL_PLATFORM} STREQUAL "DESKTOP")

cmake/external/googletest.cmake

@@ -0,0 +1,41 @@
+# Copyright 2019 Google
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+if(TARGET googletest OR NOT DOWNLOAD_GOOGLETEST)
+  return()
+endif()
+
+# Googletest 1.8.0 fails to build on VS 2017:
+# https://github.com/google/googletest/issues/1111.
+#
+# No release has been made since, so just pick a commit since then.
+set(commit ba96d0b1161f540656efdaed035b3c062b60e006)  # master@{2018-07-10}
+
+ExternalProject_Add(
+  googletest
+
+  DOWNLOAD_DIR ${FIREBASE_DOWNLOAD_DIR}
+  DOWNLOAD_NAME googletest-${commit}.tar.gz
+  URL https://github.com/google/googletest/archive/${commit}.tar.gz
+  URL_HASH SHA256=949c556896cf31ed52e53449e17a1276b8b26d3ee5932f5ca49ee929f4b35c51
+
+  PREFIX ${PROJECT_BINARY_DIR}
+
+  CONFIGURE_COMMAND ""
+  BUILD_COMMAND ""
+  INSTALL_COMMAND ""
+  TEST_COMMAND ""
+)

cmake/external_rules.cmake

@@ -61,6 +61,7 @@ function(download_external_sources)
       -DFIREBASE_EXTERNAL_PLATFORM=${external_platform}
       -DDOWNLOAD_CURL=${DOWNLOAD_CURL}
       -DDOWNLOAD_FLATBUFFERS=${DOWNLOAD_FLATBUFFERS}
+      -DDOWNLOAD_GOOGLETEST=${FIREBASE_CPP_BUILD_TESTS}
       -DDOWNLOAD_LIBUV=${DOWNLOAD_LIBUV}
       -DDOWNLOAD_NANOPB=${DOWNLOAD_NANOPB}
       -DDOWNLOAD_UWEBSOCKETS=${DOWNLOAD_UWEBSOCKETS}

cmake/test_rules.cmake

@@ -0,0 +1,39 @@
+# Copyright 2019 Google
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(CMakeParseArguments)
+
+# cc_test(
+#   target
+#   SOURCES sources...
+#   DEPENDS libraries...
+# )
+#
+# Defines a new test executable target with the given target name, sources, and
+# dependencies.  Implicitly adds DEPENDS on gtest and gtest_main.
+function(cc_test name)
+  set(multi DEPENDS SOURCES)
+  # Parse the arguments into cc_test_SOURCES and cc_test_DEPENDS.
+  cmake_parse_arguments(cc_test "" "" "${multi}" ${ARGN})
+
+  list(APPEND cc_test_DEPENDS gtest gtest_main)
+
+  add_executable(${name} ${cc_test_SOURCES})
+  add_test(${name} ${name})
+  target_include_directories(${name}
+    PRIVATE
+      ${FIREBASE_SOURCE_DIR}
+  )
+  target_link_libraries(${name} PRIVATE ${cc_test_DEPENDS})
+endfunction()