CLJS-1304: Behavior of c.string/replace differs from Clojure

JavaScript own's `String.prototype.replace` knows how to do string
replacement using functions, therefore is used as internal
implementation. But the signature differs as the js version feeds the
matched groups as variadic arguements to the replacement function. The
solution here is to create a "function adapter" between the js replace
and the replacement function.

For cases where we have a single matching string without any subgroup,
we pass it directly, without the wrapping vector.

Author: andrewhr

src/main/cljs/clojure/string.cljs

@@ -24,6 +24,18 @@
   (-> (.replace s re-surrogate-pair "$2$1")
       (.. (split "") (reverse) (join ""))))
 
+(defn- replace-all
+  [s re replacement]
+  (.replace s (js/RegExp. (.-source re) "g") replacement))
+
+(defn- replace-with
+  [f]
+  (fn [& args]
+    (let [matches (drop-last 2 args)]
+      (if (= (count matches) 1)
+        (f (first matches))
+        (f (vec matches))))))
+
 (defn replace
   "Replaces all instance of match with replacement in s.
    match/replacement can be:
@@ -36,7 +48,9 @@
     (.replace s (js/RegExp. (gstring/regExpEscape match) "g") replacement)
 
     (instance? js/RegExp match)
-    (.replace s (js/RegExp. (.-source match) "g") replacement)
+    (if (string? replacement)
+      (replace-all s match replacement)
+      (replace-all s match (replace-with replacement)))
 
     :else (throw (str "Invalid match arg: " match))))
 

src/test/cljs/clojure/string_test.cljs

@@ -13,8 +13,11 @@
   (testing "Testing string replace"
     (is (= "faabar" (s/replace "foobar" \o \a)))
     (is (= "barbarbar" (s/replace "foobarfoo" "foo" "bar")))
+    (is (= "foobarfoo" (s/replace "foobarfoo" #"ooo" s/upper-case)))
     (is (= "FOObarFOO" (s/replace "foobarfoo" #"foo" s/upper-case)))
-    (is (= "barbar)foo" (s/replace "foo(bar)foo" "foo(" "bar"))))
+    (is (= "barbar)foo" (s/replace "foo(bar)foo" "foo(" "bar")))
+    (is (= "FOO-ObarFOO-O"
+           (s/replace "foobarfoo" #"f(o)o" (fn [[m g1]] (s/upper-case (str m "-" g1)))))))
 
   (testing "Testing string join"
     (is (= "" (s/join nil)))