Draft refactor-nrepl.ns.suggest-libspecs

Part of #384

Can be tried out with:

```
(thread-first "cljr-suggest-libspecs"
  (cljr--create-msg "lib-prefix" "s"
                    "language-context" "cljc"
                    "preferred-aliases" (prin1-to-string cljr-magic-require-namespaces))
  (cljr--call-middleware-sync "suggestions")
  parseedn-read-str)
```

Author: vemv

CHANGELOG.md

@@ -2,7 +2,8 @@
 
 ## Unreleased
 
-* [#385](https://github.com/clojure-emacs/refactor-nrepl/pull/385): Fix cljr-refactor.el's `cljr-slash` when namespace fragments start with a number.
+* [#385](https://github.com/clojure-emacs/refactor-nrepl/pull/385): only `suggest-aliases` that are valid symbols. 
+  * Fixes an edge case for cljr-refactor.el's `cljr-slash`.
 
 ## 3.5.4
 

src/refactor_nrepl/middleware.clj

@@ -191,6 +191,16 @@
            :namespace-aliases (serialize-response msg aliases)
            :status :done)))
 
+(def suggest-libspecs
+  (delay
+   (require-and-resolve 'refactor-nrepl.ns.suggest-libspecs/suggest-libspecs-response)))
+
+(defn- suggest-libspecs-reply [{:keys [transport] :as msg}]
+  (reply transport
+         msg
+         :suggestions (serialize-response msg (@suggest-libspecs msg))
+         :status :done))
+
 (def ^:private find-used-publics
   (delay (require-and-resolve 'refactor-nrepl.find.find-used-publics/find-used-publics)))
 
@@ -199,20 +209,21 @@
          :used-publics (serialize-response msg (@find-used-publics msg)) :status :done))
 
 (def refactor-nrepl-ops
-  {"artifact-list" artifact-list-reply
-   "artifact-versions" artifact-versions-reply
-   "clean-ns" clean-ns-reply
-   "extract-definition" extract-definition-reply
-   "find-symbol" find-symbol-reply
-   "find-used-locals" find-used-locals-reply
-   "hotload-dependency" hotload-dependency-reply
-   "namespace-aliases" namespace-aliases-reply
-   "rename-file-or-dir" rename-file-or-dir-reply
-   "resolve-missing" resolve-missing-reply
-   "stubs-for-interface" stubs-for-interface-reply
-   "find-used-publics" find-used-publics-reply
-   "version" version-reply
-   "warm-ast-cache" warm-ast-cache-reply
+  {"artifact-list"                artifact-list-reply
+   "artifact-versions"            artifact-versions-reply
+   "clean-ns"                     clean-ns-reply
+   "cljr-suggest-libspecs"        suggest-libspecs-reply
+   "extract-definition"           extract-definition-reply
+   "find-symbol"                  find-symbol-reply
+   "find-used-locals"             find-used-locals-reply
+   "hotload-dependency"           hotload-dependency-reply
+   "namespace-aliases"            namespace-aliases-reply
+   "rename-file-or-dir"           rename-file-or-dir-reply
+   "resolve-missing"              resolve-missing-reply
+   "stubs-for-interface"          stubs-for-interface-reply
+   "find-used-publics"            find-used-publics-reply
+   "version"                      version-reply
+   "warm-ast-cache"               warm-ast-cache-reply
    "warm-macro-occurrences-cache" warm-macro-occurrences-cache-reply})
 
 (defn wrap-refactor

src/refactor_nrepl/ns/suggest_libspecs.clj

@@ -0,0 +1,54 @@
+(ns refactor-nrepl.ns.suggest-libspecs
+  "Beta middleware, meant only for internal development. Subject to change."
+  (:require
+   [refactor-nrepl.core :as core]
+   [refactor-nrepl.ns.libspecs :as libspecs]))
+
+(defn suggest-libspecs-response
+  "Very basic POC for https://github.com/clojure-emacs/refactor-nrepl/issues/384.
+
+  Only focuses on its API and giving some basic (but useful) results.
+
+  The results are returned in no particular order."
+  [{:keys [lib-prefix ;; "set", representing that the user typed `set/`
+           ^String language-context ;; "clj" "cljs" or "cljc" representing the filename extension (or a user choice for edge cases e.g. it's a buffer/repl without a filename)
+           preferred-aliases ;; the entire value of cljr-magic-require-namespaces. See also https://github.com/clojure-emacs/clj-refactor.el/issues/530 for an intended future feature.
+           suggest ;; the value of cljr-suggest-namespace-aliases
+           ignore-errors]
+    :or   {ignore-errors true
+           suggest       true}}]
+  {:pre [lib-prefix
+         language-context
+         preferred-aliases
+         (boolean? suggest)
+         (boolean? ignore-errors)]}
+  (let [alias (symbol lib-prefix)
+        aliases (libspecs/namespace-aliases ignore-errors
+                                            (core/source-dirs-on-classpath)
+                                            suggest)
+        ks      (cond-> #{}
+                  (.equals language-context "clj")  (conj :clj)
+                  (.equals language-context "cljs") (conj :cljs)
+                  (.equals language-context "cljc") (conj :clj :cljs)
+                  true                              vec)
+        maps (map (fn [k]
+                    (get aliases k))
+                  ks)
+        merged (apply merge-with (fn [x y]
+                                   (vec (distinct (into x y))))
+                      maps)
+        candidates (get merged alias)]
+    (->> candidates
+         (mapv (fn [candidate]
+                 (format "[%s :as %s]"
+                         candidate
+                         alias))))))
+
+(comment
+  (suggest-libspecs-response {:lib-prefix "add-on"
+                              :language-context "clj"
+                              :preferred-aliases []})
+
+  (suggest-libspecs-response {:lib-prefix "s"
+                              :language-context "cljc"
+                              :preferred-aliases []}))