ParseXS: refactor: add Node::TYPEMAP

(This commit is part of a series which will extend the AST parse tree
from just representing individual XSUBs to representing the whole XS
file.)

Add a new node type,

    ExtUtils::ParseXS::Node::TYPEMAP.

this (mostly) regularises the treatment of a TYPEMAP line, now handled in
the usual way by parse_keywords(), rather than being processed solely
within fetch_para(). fetch_para() does still need to do *some*
processing: it has to read the TYPEMAP line, extract out the <<EOF bit,
and use that to read lines up until the matchhing 'EOF'. It then returns
these lines (including the initial TYPEMAP line) as a paragraph which is
then handled as a normal file-scoped keyword.

With this commit, fetch_para() becomes closer to its official job of
just returning the next useful chunk of lines, rather than having hidden
side effects too.

This commit is supposed to have no changes in behaviour, but there
*might* be some edge cases that I haven't thought of.

Author: iabyn

dist/ExtUtils-ParseXS/lib/ExtUtils/ParseXS.pm

@@ -525,43 +525,6 @@ sub _maybe_skip_pod {
 }
 
 
-# Strip out and parse embedded TYPEMAP blocks (which use a HEREdoc-alike
-# block syntax).
-
-sub _maybe_parse_typemap_block {
-  my ExtUtils::ParseXS $self = shift;
-
-  # This is special cased from the usual paragraph-handler logic
-  # due to the HEREdoc-ish syntax.
-  return unless $self->{lastline} =~ /^TYPEMAP\s*:/;
-
-  $self->{lastline} =~ /^TYPEMAP\s*:\s*<<\s*(?:(["'])(.+?)\1|([^\s'"]+?))\s*;?\s*$/
-    or $self->death("Error: unparseable TYPEMAP line: '$self->{lastline}'");
-
-
-
-    my $end_marker = quotemeta(defined($1) ? $2 : $3);
-
-    # Scan until we find $end_marker alone on a line.
-    my @tmaplines;
-    while (1) {
-      $self->{lastline} = readline($self->{in_fh});
-      $self->death("Error: Unterminated TYPEMAP section") if not defined $self->{lastline};
-      last if $self->{lastline} =~ /^$end_marker\s*$/;
-      push @tmaplines, $self->{lastline};
-    }
-
-    my $tmap = ExtUtils::Typemaps->new(
-      string        => join("", @tmaplines),
-      lineno_offset => 1 + ($self->current_line_number() || 0),
-      fake_filename => $self->{in_filename},
-    );
-    $self->{typemaps_object}->merge(typemap => $tmap, replace => 1);
-
-    $self->{lastline} = "";
-}
-
-
 # fetch_para(): private helper method for process_file().
 #
 # Read in all the lines associated with the next XSUB, or associated with
@@ -672,7 +635,35 @@ sub fetch_para {
   for (;;) {
     $self->_maybe_skip_pod;
 
-    $self->_maybe_parse_typemap_block;
+    # if present, extract out a TYPEMAP block as a paragraph
+    if ($self->{lastline} =~ /^TYPEMAP\s*:/) {
+
+      # Return what we have already and process this line on the
+      # next call; that way something like a previous BOOT: won't
+      # run on into the TYPEMAP: lines
+      return 1 if @{$self->{line}};
+
+      $self->{lastline} =~
+          /^TYPEMAP\s*:\s*<<\s*(?:(["'])(.+?)\1|([^\s'"]+?))\s*;?\s*$/
+      or $self->death("Error: unparseable TYPEMAP line: '$self->{lastline}'");
+
+      my $end_marker = quotemeta(defined($1) ? $2 : $3);
+
+      # Scan until we find $end_marker alone on a line.
+      my $last;
+      while (1) {
+        unless ($last) {
+          push @{$self->{line}},    $self->{lastline};
+          push @{$self->{line_no}}, $.;
+        }
+        $self->{lastline} = readline($self->{in_fh});
+        last if $last;
+        $self->death("Error: Unterminated TYPEMAP section")
+                              unless  defined $self->{lastline};
+        $last = $self->{lastline} =~ /^$end_marker\s*$/;
+      }
+      return 1;
+    }
 
     my $final;
 

dist/ExtUtils-ParseXS/lib/ExtUtils/ParseXS/Node.pm

@@ -1058,7 +1058,6 @@ sub parse {
 
   PARAGRAPH:
     while ( ($pxs->{line} && @{$pxs->{line}}) || $pxs->fetch_para()) {
-
         if (   !defined($self->{line_no})
             && defined $pxs->{line_no}[0]
         ) {
@@ -1191,7 +1190,7 @@ sub parse {
                 undef, undef, # xsub and xbody: not needed for non XSUB keywords
                 undef,  # implies process as many keywords as possible
                  "BOOT|REQUIRE|PROTOTYPES|EXPORT_XSUB_SYMBOLS|FALLBACK"
-              . "|VERSIONCHECK|INCLUDE|INCLUDE_COMMAND|SCOPE",
+              . "|VERSIONCHECK|INCLUDE|INCLUDE_COMMAND|SCOPE|TYPEMAP",
                 $keywords_flag_MODULE,
             );
 
@@ -1376,6 +1375,46 @@ sub as_boot_code {
     return [], \@lines;
 }
 
+# ======================================================================
+
+package ExtUtils::ParseXS::Node::TYPEMAP;
+
+# Process the lines associated with the TYPEMAP keyword
+#
+# fetch_para() will have already processed the <<EOF logic
+# and read all the lines up to, but not including, the EOF line.
+
+BEGIN { $build_subclass->(
+    'lines', # Array ref of all lines making up the TYPEMAP section
+)};
+
+
+# Feed all the lines to ExtUtils::Typemaps.
+
+sub parse {
+    my __PACKAGE__       $self = shift;
+    my ExtUtils::ParseXS $pxs  = shift;
+
+    $self->SUPER::parse($pxs); # set file/line_no
+
+    shift @{$pxs->{line}}; # skip the 'TYPEMAP:' line
+
+    # Suck in all remaining lines
+    $self->{lines} = $pxs->{line};
+    $pxs->{line} = [];
+
+    my $tmap = ExtUtils::Typemaps->new(
+        string        => join("", @{$self->{lines}}),
+        lineno_offset => 1 + ($pxs->current_line_number() || 0),
+        fake_filename => $pxs->{in_filename},
+    );
+
+    $pxs->{typemaps_object}->merge(typemap => $tmap, replace => 1);
+
+    1;
+}
+
+
 # ======================================================================
 
 package ExtUtils::ParseXS::Node::pre_boot;